REQUISIS DXL-Bibliothek

Die größte DXL-Bibliothek im deutschsprachigen Raum

name:	DisplayDifferencesBetween2Modules
Type:	DXL-Layout-Column
description:	This script displays differences between two modules. (copy this script into a new column with the type layout script in DOORS)

Sourcecode:

//DisplayDifferencesBetween2Modules
/********************************************************************************************************
   REQUISIS DXL-Bibliothek
   https://requisis.com/de/dxl-bibliothek.html

Die größte DXL-Bibliothek im deutschsprachigen Raum.

*********************************************************************************************************
  (c) 2009-2017 REQUISIS GmbH
      Walter-Benjamin-Platz 8
      D-10629 Berlin

https://requisis.com

*********************************************************************************************************
Beschreibung:
Dieses Layoutscript zeigt die Unterschiede zwischen 2 Modulen an. (Dazu in Doors eine neue Spalte als Layout DXL anlegen und das Script hineinkopieren - vorher anpassen)

description:
This script displays differences between two modules. (copy this script into a new column with the type layout script in DOORS)

*********************************************************************************************************
Nutzungsrechte:

Dieses Script darf frei für die tägliche Arbeit mit Doors verwendet werden. 
Es darf beliebig in eigene Scripte integriert werden, sofern diese 
nur für den Eigengebrauch bestimmt sind.
! Die Integration in andere Produkte oder Scripte, die nicht ausschließlich für den Eigengebrauch 
! bestimmt sind, erfordert die schriftliche Zustimmung der REQUISIS GmbH.
! Die Verbreitung und Veröffentlichung dieses Scripts ist nur der REQUISIS GmbH vorbehalten.

This script may be used for daily work with IBM Rational Doors. It is allowed to include this script
into own scripts if they are only intended to be used for own purposes.
! The integration into other products or scripts, which are not soley used for own purposes 
! is not permitted.
*********************************************************************************************************
*/
   
// prevent dxl timeout dialog
pragma runLim, 0

Module mnew = current;
Module mold

/*********************************************************************************/
//Hier das Modul angeben mit dem Verglichen werden soll
/*********************************************************************************/
Module mbase_old = read("/Projekt/Ordner/Modul",false)

/*********************************************************************************/
//Hier das Attribute angeben mit dem die Objekte verglichen werden sollen
/*********************************************************************************/
string vergleichsattribut = "Absolute Number"

/*********************************************************************************/
//Hier Attribute hinzufügen (mit Komma getrennt) die NICHT verglichen werden sollen
//oder weiter unten die Attribute angeben die verglichen werden sollen
/*********************************************************************************/
string ausnahmen="Last Modified On,Last Modified By"

/*********************************************************************************/
//Hier Attribute hinzufügen (mit Komma getrennt) die verglichen werden sollen
//oder weiter oben die Attribute angeben die nicht verglichen werden sollen
/*********************************************************************************/
string vergleiche=""

/*********************************************************************************/
//Hier Angeben ob mit einer Baseline verglichen werden soll [true/false]
/*********************************************************************************/
bool use_baseline = true

/*********************************************************************************/
//Hier die Werte für die VergleichsBaseline angeben (major,minor,suffix)
/*********************************************************************************/
int old_major=1
int old_minor=6
string old_suffix=""

if(!null mbase_old)
{
    if(use_baseline)
    {

Baseline bold = baseline(old_major,old_minor,old_suffix)
        if(!null bold)mold = load(mbase_old ,bold,false)
    }
    else
    {
        mold = mbase_old
    }
}
else
{
    mold = null
    display("Zielmodul nicht gefunden!");
}
Object oldo
string vergleichs_value
Skip ausnahmeliste = create()
Skip vergleicheliste = create()

//Hilfsfunktion zum Aufspalten von Strings
Skip explode(string input, string delimiter)
{
	Buffer buf = create()
	buf = input 
	Skip return_list = create
	int i, pos1 = 0;
	int strlen = length(buf);
	int dellen = length(delimiter)
	
	for(i=0;i<strlen;i++)
	{
		if(buf[i:i+dellen-1] "" == delimiter)
		{
			put(return_list,buf[pos1:i-1] "",buf[pos1:i-1] "")
			pos1=i+dellen;
		}
	}
	if(pos1<strlen)
	{
		put(return_list,buf[pos1:i-1] "",buf[pos1:strlen-1] "")
	}
	delete(buf)
	return return_list
}

//Hilfsfunktion zum Suchen von Objekten anhand eines Attributes
Object getObject(string vergleichsattribut,string atrr_value,Module m)
{
	Object o;
	for o in m do
	{
		if(o.vergleichsattribut "" == atrr_value)
			return o;
	}
	return null;
}

ausnahmeliste = explode(ausnahmen,",")
vergleicheliste = explode(vergleiche,",")

if(null mold)
{
	display "Vergleichsmodul/Baseline nicht gefunden"
}
else
{
	vergleichs_value=obj.(vergleichsattribut)
	
	string Text=""
	string temp=""
	if(vergleichsattribut=="Absolute Number")
	{
		oldo=object(intOf(vergleichs_value))
	}
	else
	{
		oldo=getObject(vergleichsattribut,vergleichs_value,mold)
	}

if (! null oldo)
	{
		AttrDef ad
		for ad in mnew do 
		{
			if ((ad.object)&&(!ad.dxl)&& !find(ausnahmeliste,ad.name,temp)&&(vergleiche==""||find(vergleicheliste,ad.name,temp)))
			{
		    	Buffer bufCur = create()
				bufCur=obj.(ad.name)
				Buffer bufOld = create()
				
				// check if Attribute also exists in old baseline
				AttrDef adold = find(mold, (ad.name)) 
				if (adold!=null)
				{
					bufOld=oldo.(ad.name)
				} else 
				{
					bufOld=""
				}
				
				if (bufCur!=bufOld)
				{
					Buffer bufDiff = create()
					diff(bufDiff, bufOld, bufCur, "\\b\\cf1\\strike ", "\\b\\cf3\\ul ")
					Text = Text stringOf(bufDiff) " (" ad.name ")\n"
					delete(bufDiff)
				}
				
				delete(bufOld)
				delete(bufCur)
			}
		} 
		displayRichWithColor(Text)
	} 
	else
	{
        
		displayRich "{\\b new object}"
	}
}
delete ausnahmeliste
delete vergleicheliste

Dieses Script darf frei für die tägliche Arbeit mit Doors verwendet werden.
Es darf beliebig in eigene Scripte integriert werden, sofern diese nur für den Eigengebrauch bestimmt sind.

Die Integration in andere Produkte oder Scripte, die nicht ausschließlich für den Eigengebrauch bestimmt sind, erfordern die schriftliche Zustimmung der REQUISIS GmbH.
Die Verbreitung und Veröffentlichung dieses Scripts ist nur der REQUISIS GmbH vorbehalten. Die REQUISIS GmbH übernimmt für die zur Verfügung gestellten Scripte keinerlei Verantwortung.
Jegliche Haftung ist ausgeschlossen.

DXL - Library

OLE

functions

Ihr Ansprechparter

Nikolai Stein-Cieslak

Telefon:	+49 (30) 536506-711
Fax:	+49 (30) 536506-311
E-Mail:	nikolai.stein@requisis.com