REQUISIS DXL-Library

The biggest DXL Library in Europe

name:	copyAttributeValuesFromSourceModule
Type:	Standalone
description:	This script compare 2 modules by compareattribute and copies all given attributes from sourcemodule to targetmodule, if objects have the same compareattribute.

Sourcecode:

//copyAttributeValuesFromSourceModule
/********************************************************************************************************
   REQUISIS DXL-Bibliothek
   https://requisis.com/de/dxl-bibliothek.html

Die größte DXL-Bibliothek im deutschsprachigen Raum.

*********************************************************************************************************
  (c) 2009-2017 REQUISIS GmbH
      Walter-Benjamin-Platz 8
      D-10629 Berlin

https://requisis.com

*********************************************************************************************************
Beschreibung:
Dieses Script vergleicht 2 Module andhand eines Vergleichsattributes und kopiert für identische Objekte alle angegeben Attribute aus dem Quellmodul in das Zielmodul.

description:
This script compare 2 modules by compareattribute and copies all given attributes from sourcemodule to targetmodule, if objects have the same compareattribute.

*********************************************************************************************************
Nutzungsrechte:

Dieses Script darf frei für die tägliche Arbeit mit Doors verwendet werden. 
Es darf beliebig in eigene Scripte integriert werden, sofern diese 
nur für den Eigengebrauch bestimmt sind.
! Die Integration in andere Produkte oder Scripte, die nicht ausschließlich für den Eigengebrauch 
! bestimmt sind, erfordert die schriftliche Zustimmung der REQUISIS GmbH.
! Die Verbreitung und Veröffentlichung dieses Scripts ist nur der REQUISIS GmbH vorbehalten.

This script may be used for daily work with IBM Rational Doors. It is allowed to include this script
into own scripts if they are only intended to be used for own purposes.
! The integration into other products or scripts, which are not soley used for own purposes 
! is not permitted.
*********************************************************************************************************
*/
   
//Hilfsfunktion - trennt strings anhand von Zeichen und gibt eine Skipliste zurück
Skip explode(string s, char c)
{
	Buffer buf = create()
	buf = s 
	Skip list = create
	string temp
	int i=0
	int pos = contains(buf,c)
	while(pos !=-1)
	{
		temp = buf[0:pos-1]
		buf = buf[pos+1:length(buf)]
		put(list,i,temp)
		i++
		pos = contains(buf,c)
	}
	put(list,i,stringOf(buf))
	delete(buf)
	return list
}

//Laufzeitbeschränkung aufheben
pragma runLim, 0

Object osource,otarget
string sourceCompareAttribute, targetCompareAttribute, temp
int i=0
bool flag=true;
Module mtarget = current

/******************************/
/*Hier das Quellmodul anpassen*/
/******************************/
Module msource = read("/Entwicklung/Testspec_Includes_Kopie")

/**************************************/
/*Hier das Vergleichsattribut anpassen*/
/**************************************/
string compareAttribute = "Absolute Number"

/********************************************************************************************/
/*Hier String anpassen um zusätzliche Attribute zu kopieren, mehrere Attribute mit , trennen*/
/********************************************************************************************/
string copyAttributes = "test1,test2";

Skip attributeList = create();
attributeList = explode(copyAttributes,',');

//Überprüfe ob Quellmodul gelesen werden kann
if(null msource)
{
	print "Fehler - Quellmodul konnte nicht geöffnet werden.\n";
	flag=false;
}
else
{
	current = msource;
	//Überprüfe ob Vergleichsattribut im Quellmodul existiert
	if(!exists(attribute compareAttribute))
	{
		print "Fehler - Vergleichsattribut: " compareAttribute " im Quellmodul nicht vorhanden.\n";
		flag=false;
	}  
	//Überprüfe ob die Attribute im Quellmodul existieren die kopiert werden sollen
	for temp in attributeList do
	{
		if(!exists(attribute temp))
		{
			print "Fehler - Attribut: " temp " im Quellmodul nicht vorhanden.\n";
			flag=false;
		}
	}
}
current = mtarget;
//Überprüfe ob Vergleichsattribut im aktuellen Modul existiert
if(!exists(attribute compareAttribute))
{
	print "Fehler - Vergleichsattribut: " compareAttribute " im aktuellen Modul nicht vorhanden.\n";
	flag=false;
}

//Überprüfe ob aktuelles Module im Edit-Mode geöffnet ist
if(!isEdit(mtarget))
{
	print "Fehler - Aktuelles Modul nicht im Edit-Mode geöffnet.\n";
	flag=false;
}

//Falls keine Fehhler Attribute kopieren
if(flag)
{
	for otarget in mtarget do
	{
		targetCompareAttribute=otarget.compareAttribute
		for osource in msource do
		{
			sourceCompareAttribute=osource.compareAttribute
			if(sourceCompareAttribute == targetCompareAttribute)
			{
				//Alle Attribute kopieren
				for temp in attributeList do
				{
					copyAttribute_(osource, otarget, temp);
				}
				break;
			}	
		}
	}
	print "DONE";
}

Dieses Script darf frei für die tägliche Arbeit mit Doors verwendet werden.
Es darf beliebig in eigene Scripte integriert werden, sofern diese nur für den Eigengebrauch bestimmt sind.

Die Integration in andere Produkte oder Scripte, die nicht ausschließlich für den Eigengebrauch bestimmt sind, erfordern die schriftliche Zustimmung der REQUISIS GmbH.
Die Verbreitung und Veröffentlichung dieses Scripts ist nur der REQUISIS GmbH vorbehalten. Die REQUISIS GmbH übernimmt für die zur Verfügung gestellten Scripte keinerlei Verantwortung.
Jegliche Haftung ist ausgeschlossen.

DXL - Library